$ SET NOVERIFY
$ SET ON
$ !--------------------------------------------------------------------------
$ !
$ !	    S Y S _ U T I L I T Y : W A T C H D O G . B L D
$ !
$ !	Purpose:
$ ! 		Compiles and Links Watchdog Program
$ !
$ !	Original:	G. H. Walrod III
$ !	Modification:
$ !
$ !	V4.0-0	06-Dec-1985			George H. Walrod III
$ !		Add Multi Version Section so User has the Option.
$ !
$ !	V4.0-2	18-Feb-1986			George H. Walrod III
$ !		Made it So That Recompling is Neccessary
$ !
$ !	V4.1-0	19-Feb-1986			George H. Walrod III
$ !		Add Exeception Routines
$ !
$ !	V4.2-0	10-Sep-1986			George H. Walrod III
$ !		Remove V4.1 Exeception Routines and Add
$ !		Real Routines.
$ !
$ !	V5.0-0	05-May-1989			George H. Walrod III
$ !		Support of Version 5.
$ !
$ !--------------------------------------------------------------------------
$ WRITE SYS$OUTPUT "This Command file is used to Build WATCHDOG"
$ WRITE SYS$OUTPUT " "
$ !
$ !	Inquire VMS Version Number
$ !
$GET_VERSION:
$ INQUIRE version -
     "What VMS version is WATCHDOG being built for 3,4,5 (def: 5) "
$ IF version .EQS. "" THEN version = "5"
$ IF version .EQS. "3" .OR. -
     version .EQS. "4" .OR. -
     version .EQS. "5" THEN $ GOTO GOOD_VERSION
$ WRITE SYS$OUTPUT "Invalid Version Number"
$ WRITE SYS$OUTPUT " "
$ GOTO GET_VERSION
$GOOD_VERSION:
$ WRITE SYS$OUTPUT " "
$ !
$ !	Inquire for Recompile with Debug
$ !
$ INQUIRE debugger -
     "Do you need the Debugger(def: N) "
$ IF debugger .EQS. "" THEN debugger = "N"
$ WRITE SYS$OUTPUT " "
$ debug_link  = "/NOTRACEBACK"
$ macro_debug = " "
$ debug_comp  = " "
$ IF F$EXTRACT(0,1,debugger) .NES. "Y" THEN GOTO CHECK_DLINES
$ debug_comp  = "/DEBUG/NOOPTIMIZE"
$ macro_debug = "/DEBUG"
$ debug_link  = "/DEBUG/TRACEBACK"
$ !
$ !	Inquire for Recompile with D_LINES for Fortran Compiles
$ !
$CHECK_DLINES:
$ IF version .NES. "3" THEN GOTO SETSRC_PROGRAM
$ INQUIRE dlines -
     "Do you need the D_Lines Option(def: N) "
$ IF dlines .EQS. "" THEN dlines = "N"
$ WRITE SYS$OUTPUT " "
$ IF F$EXTRACT(0,1,dlines) .NES. "Y" THEN GOTO SETSRC_PROGRAM
$ debug_comp  = "''debug_comp'/D_LINES"
$ !
$ !	Set Version of Watchdog Source
$ !
$SETSRC_PROGRAM:
$ IF version .NES. "3" THEN GOTO SETSRC_4_5_X
$ !
$ !	Compile WATCHDOG.FOR
$ !
$COMPILE_PROGRAM:
$ WRITE SYS$OUTPUT "Recompiling Version 3.X of Watchdog"
$ FORTRAN/LIST/CROSS/CONTIN=99 WATCHDOG.FOR 'debug_comp'
$ !
$ !	Assemble WATCHSYM.MAR
$ !
$ WRITE SYS$OUTPUT "Assembling Watchsym Macro"
$ MACRO/LIST WATCHSYM.MAR
$ LIBRARY/CREATE WATCHDOG WATCHSYM
$ !
$ !	LINK WATCHDOG
$ !
$LINK_PROGRAM:
$ WRITE SYS$OUTPUT "Linking Version 3.x Watchdog"
$ LINK/MAP WATCHDOG, WATCHDOG/INCLUDE=WATCHSYM/LIBRARY/SELECTIVE  'debug_link'
$ GOTO EXIT
$ !
$ !	Copy Source to Set Correct Source for VMS
$ !
$SETSRC_4_5_X:
$ COPY WATCHDOG_'version'.MAR WATCHDOG.MAR
$ !
$ !	Assembling V4/5.x WATCHDOG.MAR
$ !
$ASSEMBLE_PROGRAM:
$ WRITE SYS$OUTPUT "Assembling ''version'.x Watchdog"
$ MACRO/LIST WATCHDOG.MAR 'macro_debug'
$ !
$ !	Link WATCHDOG Version 4/5.X
$ !
$LINK_PROGRAM:
$ WRITE SYS$OUTPUT "Linking Version ''version'.x Watchdog"
$ LINK/MAP 'debug_link' WATCHDOG
$ !
$ !	EXITING
$ !
$EXIT:
$ WRITE SYS$OUTPUT "Complete"
$ EXIT