$!*****************************************************************************
$! AKRUN.COM
$!
$!	  AKCOUNT Site Specific Command Procedure
$!
$!	Written by : M. Serrer   DME/NRC  Systems Lab.
$!	           : K. Trumbley DME/NRC  Systems Lab.
$!	Date       : Aug 1984
$!
$!*****************************************************************************
$!
$!
$	AKTIME:==$SYS$ACCOUNT:AKTIME.EXE
$	AKTIME FRIDAY,23:59:59
$	AK_FISCAL:=='AK_FISCAL'
$	AK_DATE:=='AK_DATE'
$	IF P1.EQS."RESTART" THEN $EXIT
$!
$	SET DEFAULT SYS$SYSTEM:
$!
$! Create SYSUAF.LIS
$!
$	DELETE SYS$SYSTEM:SYSUAF.LIS;*
$	RUN SYS$SYSTEM:AUTHORIZE
LIST/BRIEF
EXIT
$!
$! Create DSKUSG.LIS of all disks present on system
$!
$	DELETE SYS$SYSTEM:DSKUSG.LIS;*
$	ASS/USER DISKLIST.LIS SYS$OUTPUT
$	SHOW DEVICE D
$	OPEN/WRITE FILE AKGETUSG.COM
$	WRITE FILE "$ ASSIGN/USER SYS$SYSTEM:DSKUSG.LIS SYS$OUTPUT"
$	WRITE FILE "$ RUN SYS$SYSTEM:DISKQUOTA"
$	OPEN/READ DISK_LIST DISKLIST.LIS
$	READ/END=XLOOP/ERR=XLOOP DISK_LIST LINE
$	READ/END=XLOOP/ERR=XLOOP DISK_LIST LINE
$	READ/END=XLOOP/ERR=XLOOP DISK_LIST LINE
$LOOP:
$	READ/END=XLOOP/ERR=XLOOP DISK_LIST LINE
$	L1:='F$LOCATE(":",LINE)
$	DEVICE:='F$EXTRACT(L1-4,5,LINE)
$	DEV_MNT:='F$GETDVI(DEVICE,"MNT")'
$	IF DEV_MNT .EQS. "FALSE" THEN GOTO LOOP
$	WRITE FILE "USE ''DEVICE'"
$	WRITE FILE "SHOW [*,*]"
$	GOTO LOOP
$XLOOP:
$	WRITE FILE "EXIT"
$	CLOSE FILE
$	CLOSE DISK_LIST
$	DELETE DISKLIST.LIS;*
$	@AKGETUSG.COM
$	DELETE AKGETUSG.COM;*
$!
$!
$!
$! Now run AKCOUNT.EXE
$!
$	SET DEFAULT SYS$ACCOUNT:
$	RUN SYS$ACCOUNT:AKCOUNT.EXE
$	REPORT:==$SYS$ACCOUNT:AKREPORT.EXE
$!
$! Run REPORT generator
$!
$!   WEEKLY SUMMARY
$!
$	REPORT */SUMMARY/OUTPUT=AKCOUNT.LIS
$!
$!   YEAR TO DATE SUMMARY
$!
$!	REPORT */SUMMARY/BEGIN='AK_START'/OUTPUT=AKCOUNT.LIS
$!
$!   DETAILED SINGLE USER
$!
$!	REPORT username/OUTPUT=AKCOUNT.LIS
$!
$!   DETAILED SINGLE USER WITH CHARGE RATE TABLE
$!
$!	REPORT username/RATE_TABLE/OUTPUT=AKCOUNT.LIS
$!
$! Print/delete all AKCOUNT.LIS files
$!
$	PRINT/NOHEADER/FLAG/DELETE AKCOUNT.LIS;*
$!
$	EXIT