//
//   COMPONENT_NAME: somi
//
//   ORIGINS: 27
//
//
//   10H9767, 10H9769  (C) COPYRIGHT International Business Machines Corp. 1992,1994
//   All Rights Reserved
//   Licensed Materials - Property of IBM
//   US Government Users Restricted Rights - Use, duplication or
//   disclosure restricted by GSA ADP Schedule Contract with IBM Corp.
//
//  ParameterDef: CORBA Interface for parameter definitions
//  See CORBA 7.5.7, p.136
#ifndef paramdef_idl
#define paramdef_idl
#include <containd.idl>
#include <somcls.idl>
// CORBA 7.5.7, p.136
interface ParameterDef : Contained
{
    enum ParameterMode {IN, OUT, INOUT};
    struct ParameterDescription {
	Identifier    name;
	RepositoryId  id;
	RepositoryId  defined_in;
	TypeCode      type;
	ParameterMode mode;
    };
    // The inherited describe method returns an instance of this
    // (ParameterDescription) structure in the "value" member of the
    // Description structure defined in the Contained interface.
    attribute TypeCode type;
    // The TypeCode of the receiving object.  The memory used to hold
    // the TypeCode is contained in the receiving object, which retains
    // ownership.  Hence, do not free the returned TypeCode.  If you want
    // to obtain a separate copy, use the TypeCode_copy operation.
    attribute ParameterMode mode;
    // The ParameterMode of the receiving object;
#ifdef __SOMIDL__
  implementation {
      releaseorder: _get_type,_set_type,_get_mode,_set_mode;
      callstyle = idl;
      majorversion = 2;
      minorversion = 1;
      filestem = paramdef;
      dllname = "somir.dll";
      passthru C_h =
	""
	"    #include <somtcnst.h>"
	"    #include <somir.h>"
	"    #include <containd.h>"
	"";
      passthru C_xh =
	""
	"    #include <somtcnst.xh>"
	"    #include <somir.xh>"
	"    #include <containd.xh>"
	"";
      type: nodata;
      mode: noget, noset;
      somInit: override;
      somUninit: override;
      somDumpSelf: override;
      somDumpSelfInt: override;
      describe: override;
  };
#endif /* __SOMIDL__ */
};
#endif	/* paramdef_idl */
